ampage
Tube Amps / Music Electronics
For current discussions, please visit Music Electronics Forum. The sunn still shines online!

ampage archive

Vintage threads from the first ten years

Search for:  Mode:  

tm too


 :
4/16/2000 11:50 PM
Ken Gilbert
tm too
also found a patch for traxmaker:  
 
http://www.juston.com/vfs/pdownload.cgi/ride5000/390496/cor_tm30.exe  
 
probably not too many folks around here making pcb's, but you never know.  
same instructions apply for this patch as well.  
 
kg
 
4/16/2000 11:54 PM
Ken Gilbert
tube library models supplied by GFR
From: gfr@cepel.br  
Date: Wed, 5 Apr 2000 08:32:29 -0300  
Subject: circuit maker libraries  
 
Obs:  
1) put on "C:Program FilesMicroCode EngineeringCircuitMaker 6  
PROModels" directory;  
2) when you have DM on the model name it's from Duncan amps site;  
3) I didn't care about the "package" part of the models, so you can't use it  
to design a PCB without first editing the models.  
 
GFR  
 
*======================================  
*Triode Pinouts: Plate Grid Cathode  
*======================================  
 
*Vacuum Tube Triode (Audio freq.)  
.SUBCKT X6SN7 1 3 4  
B1 2 4 I=((URAMP((V(2,4)/20)+V(3,4)))^1.5)/1086  
C1 3 4 2.6E-12  
C2 3 1 4.0E-12  
C3 1 4 0.7E-12  
R1 3 5 10E+3  
D1 1 2 DX  
D2 4 2 DX2  
D3 5 4 DX  
.MODEL DX D(IS=1.0E-12 RS=1.0)  
.MODEL DX2 D(IS=1.0E-9 RS=1.0)  
.ENDS X6SN7  
 
*Vacuum Tube Triode (Audio freq.) pkg:VT-9 (A:1,2,3)(B:6,7,8)  
.SUBCKT X12AU7 1 3 4  
B1 2 4 I=((URAMP((V(2,4)/18)+V(3,4)))^1.5)/1151  
C1 3 4 1.6E-12  
C2 3 1 1.5E-12  
C3 1 4 0.5E-12  
R1 3 5 10E+3  
D1 1 2 DX  
D2 4 2 DX2  
D3 5 4 DX  
.MODEL DX D(IS=1.0E-12 RS=1.0)  
.MODEL DX2 D(IS=1.0E-9 RS=1.0)  
.ENDS X12AU7  
 
*Vacuum Tube Triode (Audio freq.) pkg:VT-9 (A:1,2,3)(B:6,7,8)  
.SUBCKT X12AX7 1 3 4  
B1 2 4 I=((URAMP((V(2,4)/85)+V(3,4)))^1.5)/580  
C1 3 4 1.6E-12  
C2 3 1 1.7E-12  
C3 1 4 0.46E-12  
R1 3 5 50E+3  
D1 1 2 DX  
D2 4 2 DX2  
D3 5 4 DX  
.MODEL DX D(IS=1.0E-12 RS=1.0)  
.MODEL DX2 D(IS=1.0E-9 RS=1.0)  
.ENDS X12AX7  
 
*Vacuum Tube Triode (Audio freq.)  
.SUBCKT X7199T 1 3 4  
B1 2 4 I=((URAMP((V(2,4)/17)+V(3,4)))^1.5)/711  
C1 3 4 2.3E-12  
C2 3 1 2.0E-12  
C3 1 4 0.3E-12  
R1 3 5 5E+3  
D1 1 2 DX  
D2 4 2 DX2  
D3 5 4 DX  
.MODEL DX D(IS=1.0E-12 RS=1.0)  
.MODEL DX2 D(IS=1.0E-9 RS=1.0)  
.ENDS X7199T  
 
*Vacuum Tube Triode (Audio freq.) pkg:VT-9 [grid current + low B+] (A:1,2,3)(B:6,7,8)  
.SUBCKT X12AT7 1 2 3  
B1 7 0 V=(V(1,3)/267*LOG(1+EXP(267*(1/58.5+V(2,3)/SQRT(1849+V(1,3)*V(1,3))))))  
RE1 7 0 1G  
B2 1 3 I= 2*URAMP(V(7)^1.23)/659  
RCP 1 3 1G ; TO AVOID FLOATING NODES IN MU-FOLLOWER  
C1 2 3 1.6P ; CATHODE GRID  
C2 2 1 1.6P ; GRID-PLATE  
C3 1 3 0.33P ; CATHODE-PLATE  
D3 5 3 DX ; FOR GRID CURRENT  
R1 2 5 2000 ; FOR GRID CURRENT  
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)  
.ENDS X12AT7  
 
 
*Vacuum Tube Triode (Audio freq.) pkg:VT-9 [grid current + low B+] (A:1,2,3)(B:6,7,8)  
.SUBCKT X12AX7A 1 2 3  
B1 7 0 V=(V(1,3)/682*LOG(1+EXP(682*(1/107.6+V(2,3)/SQRT(8837+V(1,3)*V(1,3))))))  
RE1 7 0 1G  
B2 1 3 I= 2*URAMP(V(7)^1.03)/851  
RCP 1 3 1G ; TO AVOID FLOATING NODES IN MU-FOLLOWER  
C1 2 3 1.6P ; CATHODE GRID  
C2 2 1 1.6P ; GRID-PLATE  
C3 1 3 0.33P ; CATHODE-PLATE  
D3 5 3 DX ; FOR GRID CURRENT  
R1 2 5 2000 ; FOR GRID CURRENT  
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)  
.ENDS X12AX7A  
 
*Vacuum Tube Triode (Audio freq.) pkg:VT-9 [grid current + low B+] (A:1,2,3)(B:6,7,8)  
.SUBCKT XECC82 1 2 3  
B1 7 0 V=(V(1,3)/83.31*LOG(1+EXP(83.31*(1/19.84+V(2,3)/SQRT(562.6+V(1,3)*V(1,3))))))  
RE1 7 0 1G  
B2 1 3 I= 2*URAMP(V(7)^1.234)/1258  
RCP 1 3 1G ; TO AVOID FLOATING NODES IN MU-FOLLOWER  
C1 2 3 1.6P ; CATHODE GRID  
C2 2 1 1.5P ; GRID-PLATE  
C3 1 3 0.36P ; CATHODE-PLATE  
D3 5 3 DX ; FOR GRID CURRENT  
R1 2 5 2000 ; FOR GRID CURRENT  
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)  
.ENDS XECC82  
 
* WE300B Triode PSpice Model (Audio freq.) pkg:VT-9 (A:1,2,3)(B:6,7,8)  
.SUBCKT XWE300B P G K  
BE1 2 0 V=V(P,K)+3.87*V(G,K)  
R1 2 0 1.0K  
BGp P K I=119.5E-6*URAMP(V(2)^1.5)  
Cgk G K 9.0P  
Cgp G P 15P  
Cpk P K 4.3P  
.ENDS XWE300B  
 
*Vacuum Tube Triode (Audio freq.) pkg:VT-9 [Koren / JC] (A:1,2,3)(B:6,7,8)  
.SUBCKT X12AX7AJC 1 2 3  
B1 7 0 V=(V(1,3)/600*LOG(1+EXP(600*(1/100+V(2,3)/SQRT(300+V(1,3)*V(1,3))))))  
RE1 7 0 1G  
B2 1 3 I= 2*URAMP(V(7)^1.4)/1060  
RCP 1 3 1G ; TO AVOID FLOATING NODES IN MU-FOLLOWER  
C1 2 3 1.6P ; CATHODE GRID  
C2 2 1 1.6P ; GRID-PLATE  
C3 1 3 0.33P ; CATHODE-PLATE  
D3 5 3 DX ; FOR GRID CURRENT  
R1 2 5 2000 ; FOR GRID CURRENT  
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)  
.ENDS X12AX7A  
 
*Vacuum Tube Triode (Audio freq.) pkg:VT-9 [Maillet] (A:1,2,3)(B:6,7,8)  
.subckt XRCA12ax7 1 2 3  
*************************  
BeGIogVpc 20 0 V=log(v(1,3))  
rGlogVpc 20 0 1  
eG0 10 0 poly(1) (2,3) -3.7694e+00 1.9947e+00 5.9432e-02  
eG1 11 0 poly(1) (2,3) -3.2024e-02 -4.1443e-02 -4.8236e-03  
eG2 12 0 poly(1) (2,3) 1.9127e-02 -1.2189e-02 -1.5526e-03  
eG3 13 0 poly(1) (2,3) -1.1354e-02 4.9339e-03 6.1016e-04  
rG0 10 0 1  
rG1 11 0 1  
rG2 12 0 1  
rG3 13 0 1  
BgG 2 3 I=(exp(v(10)+v(20)*(v(11)+v(20)*(v(12)+v(20)*v(13)))))/170  
eP0 110 0 poly(1) (2,3) -9.9158e+0 1.9145e+0 -2.8135e+0 1.8661e+0  
+ 1.5643e+0 4.7240e-1 6.4276e-2 3.3101e-3  
eP1 111 0 poly(1) (2,3) 9.5428e-1 3.2558e-2 -8.3349e-1 -4.8578e-2  
+ 2.6213e-1 1.0492e-1 1.8921e-2 1.3632e-3  
eP2 112 0 poly(1) (2,3) 9.5766e-2 2.5192e-2 2.2391e-1 -1.7040e-1  
+ -2.4952e-1 -1.0960e-1 -2.0981e-2 -1.4882e-3  
eP3 113 0 poly(1) (2,3) -6.6107e-2 -3.9657e-2 7.5560e-2 3.1025e-2  
+ 2.4265e-2 1.7002e-2 4.2512e-3 3.4761e-4  
eP4 114 0 poly(1) (2,3) 8.4148e-3 4.7989e-3 -1.3258e-2 -1.9288e-3  
+ 5.2888e-4 -5.6853e-4 -2.4727e-4 -2.4359e-5  
rP0 110 0 1  
rP1 111 0 1  
rP2 112 0 1  
rP3 113 0 1  
rP4 114 0 1  
BgP 1 3 I=(exp(v(110)+v(20)*(v(111)+v(20)*(v(112)+v(20)*(v(113)+v(20)*v(114))))))  
Cgc 2 3 1.8p  
Cgp 2 1 1.7p  
Cpc 1 3 1.9p  
.ends XRCA12ax7  
 
*Vacuum Tube Triode (Audio freq.) pkg:VT-9 [DM] (A:1,2,3)(B:6,7,8)  
.SUBCKT XDM12AX7A A G K  
*  
* Calculate contribution to anode current  
*  
Bca ca 0 V=45+V(A,K)+95.43*V(G,K)  
*  
* Reduction at low va  
*  
Bre re 0 V=URAMP(V(A,K)/5)-URAMP(V(A,K)/5-1)  
Baa A K I=V(re)*1.147E-6*(URAMP(V(ca))^1.5)  
*  
* Grid current  
*  
Bgg G K I=5E-6*(URAMP(V(G,K)+0.2)^1.5)  
*  
* Capacitances  
*  
Cgk G K 1.6P  
Cgp G A 1.7P  
Cpk A K 0.46P  
.ENDS XDM12AX7A  
 
 
*Vacuum Tube Triode (Audio freq.) pkg:VT-9 [DM] (A:1,2,3)(B:6,7,8)  
.SUBCKT XGT300B A G K  
* ANODE MODEL  
BLIM LI 0 V=(URAMP(V(A)-V(K))^ 1 )* 10  
BGG GG 0 V=V(G)-V(K)- 0  
BRP1 RP1 0 V=URAMP(-V(GG)* 0.00311 )  
BRP2 RP2 0 V=V(RP1)-URAMP(V(RP1)-0.999)  
BRPF RP 0 V=(1-V(RP2)^ 1.013608 )+URAMP(V(GG))* 0  
BGR GR 0 V=URAMP(V(GG))-URAMP(-(V(GG)*(1+V(GG)* 0.000362 )))  
BEM EM 0 V=URAMP(V(A)-V(K)+V(GR)* 3.7992 )  
BEP EP 0 V=(V(EM)^ 1.5 )*V(RP)* 0.000116  
BEL1 EL1 0 V=URAMP(V(EP))  
BEL EL 0 V=V(EL1)-URAMP(V(EL1)-V(LI))  
BLD LD 0 V=URAMP(V(EP)-V(LI))  
BAK A K I=V(EL)  
* GRID MODEL  
BGF GF 0 V=(URAMP(V(G)-V(K)- 0 )^1.5)* 0  
BG G K I=V(GF)+V(LD)  
* CAPS  
CAK A K 0.0000000000043  
CGK G K 0.000000000009  
CGA G A 0.000000000015  
.ENDS XGT300B  
 
*Vacuum Tube Triode (Audio freq.) pkg:VT-9 [DM] (A:1,2,3)(B:6,7,8)  
.SUBCKT XGT12AX7 A G K  
* ANODE MODEL  
BLIM LI 0 V=(URAMP(V(A)-V(K))^ 1.5 )* 0.000016  
BGG GG 0 V=V(G)-V(K)-0.53056  
BRP1 RP1 0 V=URAMP(-V(GG)* 0.076498 )  
BRP2 RP2 0 V=V(RP1)-URAMP(V(RP1)-0.999)  
BRPF RP 0 V=(1-V(RP2)^ 1 )+URAMP(V(GG))* 0.18  
BGR GR 0 V=URAMP(V(GG))-URAMP(-(V(GG)*(1+V(GG)*-0.013621 )))  
BEM EM 0 V=URAMP(V(A)-V(K)+V(GR)* 87.302 )  
BEP EP 0 V=(V(EM)^ 1.5 )*V(RP)* 0.00000111  
BEL1 EL1 0 V=URAMP(V(EP))  
BEL EL 0 V=V(EL1)-URAMP(V(EL1)-V(LI))  
BLD LD 0 V=URAMP(V(EP)-V(LI))  
BAK A K I=V(EL)  
* GRID MODEL  
BGF GF 0 V=(URAMP(V(G)-V(K)-0.2 )^1.5)* 0.00001  
BG G K I=V(GF)+V(LD)  
* CAPS  
CAK A K 0.0000000000007  
CGK G K 0.0000000000024  
CGA G A 0.0000000000039  
.ENDS XGT12AX7  
 
*Vacuum Tube Triode (Audio freq.) pkg:VT-9 [DM] (A:1,2,3)(B:6,7,8)  
.SUBCKT XGT12AU7 A G K  
* ANODE MODEL  
BLIM LI 0 V=(URAMP(V(A)-V(K))^ 1 )* 0.0037  
BGG GG 0 V=V(G)-V(K)- 0  
BRP1 RP1 0 V=URAMP(-V(GG)* 0.0041813 )  
BRP2 RP2 0 V=V(RP1)-URAMP(V(RP1)-0.999)  
BRPF RP 0 V=(1-V(RP2)^ 16.48 )+URAMP(V(GG))* 0.032  
BGR GR 0 V=URAMP(V(GG))-URAMP(-(V(GG)*(1+V(GG)* 0.006488 )))  
BEM EM 0 V=URAMP(V(A)-V(K)+V(GR)* 14.036 )  
BEP EP 0 V=(V(EM)^ 1.35 )*V(RP)* 0.0000236  
BEL1 EL1 0 V=URAMP(V(EP))  
BEL EL 0 V=V(EL1)-URAMP(V(EL1)-V(LI))  
BLD LD 0 V=URAMP(V(EP)-V(LI))  
BAK A K I=V(EL)  
* GRID MODEL  
BGF GF 0 V=(URAMP(V(G)-V(K)- 0 )^1.5)* 0.00012  
BG G K I=V(GF)+V(LD)  
* CAPS  
CAK A K 0.00000000000045  
CGK G K 0.0000000000018  
CGA G A 0.0000000000016  
.ENDS XGT12AU7  
 
*Vacuum Tube Triode (Audio freq.) pkg:VT-9 [DM] (A:1,2,3)(B:6,7,8)  
.SUBCKT XGT12AT7 A G K  
* ANODE MODEL  
BLIM LI 0 V=(URAMP(V(A)-V(K))^ 1 )* 0.0037  
BGG GG 0 V=V(G)-V(K)--0.5  
BRP1 RP1 0 V=URAMP(-V(GG)* 0.09869 )  
BRP2 RP2 0 V=V(RP1)-URAMP(V(RP1)-0.999)  
BRPF RP 0 V=(1-V(RP2)^ 1 )+URAMP(V(GG))* 0.1  
BGR GR 0 V=URAMP(V(GG))-URAMP(-(V(GG)*(1+V(GG)* 0.012937 )))  
BEM EM 0 V=URAMP(V(A)-V(K)+V(GR)* 45.093 )  
BEP EP 0 V=(V(EM)^ 1.4 )*V(RP)* 0.00000863  
BEL1 EL1 0 V=URAMP(V(EP))  
BEL EL 0 V=V(EL1)-URAMP(V(EL1)-V(LI))  
BLD LD 0 V=URAMP(V(EP)-V(LI))  
BAK A K I=V(EL)  
* GRID MODEL  
BGF GF 0 V=(URAMP(V(G)-V(K)--0.5 )^1.5)* 0.00012  
BG G K I=V(GF)+V(LD)  
* CAPS  
CAK A K 0.0000000000004  
CGK G K 0.0000000000023  
CGA G A 0.0000000000016  
.ENDS XGT12AT7*==========================================  
*Tetrode Pinouts: Plate Screen Grid Cathode  
*==========================================  
 
*Vacuum Tube Tetrode (Audio freq.)  
.SUBCKT X7199P 1 6 3 4  
B1 2 4 I=(((URAMP((V(7,4)/20)+V(3,4)))^1.5)/1206)*ATAN(V(1,4)/10)  
B2 7 4 I=((URAMP((V(7,4)/20)+V(3,4)))^1.5)/2562  
C1 3 4 5.0P  
C2 3 1 0.06P  
C3 1 4 2.0P  
R1 3 5 5K  
R2 2 4 2.5MEG  
D1 1 2 DX  
D2 4 2 DX2  
D3 5 4 DX  
D4 6 7 DX  
D5 4 7 DX2  
.MODEL DX D(IS=1.0P RS=1.0)  
.MODEL DX2 D(IS=1.0N RS=1.0)  
.ENDS X7199P  
 
*Vacuum Tube Tetrode (Audio freq.)  
.SUBCKT X5879 1 6 3 4  
B1 2 4 I=(((URAMP((V(7,4)/20)+V(3,4)))^1.5)/2406)*ATAN(V(1,4)/10)  
B2 7 4 I=((URAMP((V(7,4)/20)+V(3,4)))^1.5)/6988  
C1 3 4 2.7P  
C2 3 1 0.11P  
C3 1 4 2.4P  
R1 3 5 15K  
R2 2 4 2.5MEG  
D1 1 2 DX  
D2 4 2 DX2  
D3 5 4 DX  
D4 6 7 DX  
D5 4 7 DX2  
.MODEL DX D(IS=1.0P RS=1.0)  
.MODEL DX2 D(IS=1.0N RS=1.0)  
.ENDS X5879  
 
*Vacuum Tube Tetrode (Audio freq.)  
.SUBCKT X6L6GC 1 6 3 4  
B1 2 4 I=(((URAMP((V(7,4)/8)+V(3,4)))^1.5)/1456)*ATAN(V(1,4)/10)  
B2 7 4 I=((URAMP((V(7,4)/8)+V(3,4)))^1.5)/9270  
C1 3 4 10P  
C2 3 1 0.6P  
C3 1 4 6.5P  
R1 3 5 1.5K  
R2 2 4 100K  
D1 1 2 DX  
D2 4 2 DX2  
D3 5 4 DX  
D4 6 7 DX  
D5 4 7 DX2  
.MODEL DX D(IS=1.0P RS=1.0)  
.MODEL DX2 D(IS=1.0N RS=1.0)  
.ENDS X6L6GC  
 
*Vacuum Tube Tetrode (Audio freq.)  
.SUBCKT X6V6 A S G K  
*  
* Calculate contribution to cathode current  
*  
BEat at 0 V=0.636*ATAN(V(A,K)/10)  
BEme me 0 V=(URAMP(V(A,K))^1.5)/1300  
BEgs gs 0 V=URAMP(V(A,K)/600+V(S,K)/14+V(G,K)*0.65)  
BEgs2 gs2 0 V=(V(gs)^1.5)*1.45E-3  
BEsd sd 0 V=URAMP(V(gs2)*V(at)-V(me))  
BEcath cc 0 V=V(gs2)*V(at)-V(sd)  
*  
* Calculate anode current  
*  
BGa A K I=V(cc)  
*  
* Calculate screen current  
*  
BEscrn sc 0 V=0.7*V(gs2)*(1.1-V(at))  
BGs S K I=V(sc)*(URAMP(V(S,K))-URAMP(V(S,K)-10))/10  
*  
* Grid current  
*  
BGg G K I=(URAMP(V(G,K)+1)^1.5)*(1.25-V(at))*650E-6  
*  
* Capacitances  
*  
Cg1 G K 7.5p  
Cak A K 9p  
Cg1a G A 0.7p  
.ENDS X6V6  
 
 
*Vacuum Tube Pentode (Audio freq.)  
.SUBCKT XEF86 A S G K  
*  
* Calculate reduction in mu when Vg < -3V  
*  
Bmu mu 0 V=V(G,K)+URAMP(V(K,G)-3)*0.4  
*  
* Calculate contribution to cathode current  
*  
Bat at 0 V=0.636*ATAN(V(A,K)/15)  
Bgs gs 0 V=URAMP(V(S,K)/27.5+V(mu)*1.32+1)  
Bgs2 gs2 0 V=URAMP(V(gs))^1.5  
Bcath cc 0 V=V(gs2)*V(at)  
*  
* Calculate anode current  
*  
Ba A K I=5.83E-4*V(cc)  
*  
* Calculate screen current  
*  
Bs S K I=0.5E-3*V(gs2)*(1.1-V(at))  
*  
* Capacitances  
*  
Cg1 G K 3.8p  
Cak A K 5.3p  
Cg1a G A 0.05p  
 
.ENDS XEF86  
 
*Vacuum Tube Tetrode (Audio freq.)  
.SUBCKT XDM6L6 A S G K  
*  
* Calculate contribution to cathode current  
*  
Bat at 0 V=0.636*ATAN(V(A,K)/5)  
Bme me 0 V=(URAMP(V(A,K))^1.5)/1750  
Bmup mup 0 V=1-(URAMP(V(K,G)-30)/2000)  
Bmu mu 0 V=V(G,K)*V(mup)  
Bgs gs 0 V=URAMP(URAMP(V(A,K)/2.5)+V(S,K)*15.15+V(mu)*134)  
Bgs2 gs2 0 V=(V(gs)^1.5)*0.8E-6  
Bsd sd 0 V=URAMP(V(gs2)*V(at)-V(me))  
Bcath cc 0 V=V(gs2)*V(at)-V(sd)  
*  
* Calculate anode current  
*  
Ba A K I=V(cc)  
*  
* Calculate screen current  
*  
Bscrn sc 0 V=0.76*V(gs2)*(1.1-V(at))  
Bs S K I=V(sc)  
*  
* Grid current  
*  
Bg G K I=(URAMP(V(G,K)+1)^1.5)*(1.25-V(at))*650E-6  
*  
* Capacitances  
*  
Cg1 G K 5.0p  
Cgs G S 5.0p  
Cak A K 6.5p  
Cg1a G A 0.6p  
 
.ENDS XDM6L6  
 
*Vacuum Tube Pentode (Audio freq.)  
.SUBCKT X6CA7 A S G K  
*  
* Calculate contribution to cathode current  
*  
Bat at 0 V=0.636*ATAN(V(A,K)/23)  
Bgs gs 0 V=URAMP(V(S,K)/9.3+V(G,K)*0.95)  
Bgs2 gs2 0 V=V(gs)^1.5  
Bcath cc 0 V=V(gs2)*V(at)  
*  
* Calculate anode current  
*  
Ba A K I=1.86E-3*V(cc)  
*  
* Calculate screen current  
*  
Bscrn sc 0 V=V(gs2)*(1.1-V(at))  
Bs S K I=1.518E-3*V(sc)  
*  
* Grid current (approximation - does not model low va/vs)  
*  
Bg G K I=(URAMP(V(G,K)+1)^1.5)*50E-6  
*  
* Capacitances  
*  
Cg1 G K 15.4p  
Cak A K 8.4p  
Cg1a G A 1.1p  
 
.ENDS X6CA7  
 
*Vacuum Tube Pentode (Audio freq.)  
.SUBCKT X6BQ5 A S G K  
*  
* Calculate contribution to cathode current  
*  
Bat at 0 V=0.636*ATAN(V(A,K)/15)  
Bgs gs 0 V=URAMP(V(S,K)/19+V(G,K)+V(A,K)/1400)  
Bgs2 gs2 0 V=V(gs)^1.5  
Bcath cc 0 V=V(gs2)*V(at)  
*  
* Calculate anode current  
*  
Ba A K I=3.2E-3*V(cc)  
*  
* Calculate screen current  
*  
Bscrn sc 0 V=V(gs2)*(1.1-V(at))  
Bs S K I=2.0E-3*V(sc)  
*  
* Grid current (approximation - does not model low va/vs)  
*  
Bg G K I=(URAMP(V(G,K)+1)^1.5)*50E-6  
*  
* Capacitances  
*  
Cg1 G K 10.8p  
Cak A K 6.5p  
Cg1a G A 0.5p  
 
.ENDS X6BQ5  
 
*Vacuum Tube Pentode (Audio freq.)  
.SUBCKT XKT88 P S G K  
BEsp 2 0 V=V(P,K)+24.49*V(S,K)+189.9*V(G,K)  
BE1 3 2 V=8.301E-7*URAMP(V(2)^1.5)  
BE2 3 4 V=8.301E-7*(24.49*V(S,K)^1.5)*V(P,K)/40  
BE3 5 4 V=(1-V(4,2)/ABS(V(4,2)+0.001))/2  
R1 5 0 1.0K  
BGk S K I=V(3,2)  
BGp P S I=0.95*(V(3,4)*(1-V(5,4))+V(3,2)*V(5,4))  
Cgk G K 8.0P  
Cgs G S 8.0P  
Cgp G P 1.2P  
Cpk P K 12P  
.ENDS XKT88
 
4/17/2000 9:47 AM
Liam

Ken,  
 
Thanks, that was what I was after. Couple of questions though!  
 
What should it be called? I assume I use a .sub extension, but do I need to modify any libraries.  
 
Are there any tricks to get CM6 to link to it in the models? I realise I've got to check all the pin connections to get the "package" part working.  
 
Sorry if these questions are a bit dumb, but I'm not too good with modern software packages.  
 
Thanks again. I'm very impressed with this package.  
 
Liam
 
4/17/2000 5:00 PM
Kremator

Hello,  
just an opinion, but isn't ORCAD PSpice better? It seems much friendlier to me. But the demo is not crackable, or is it?  
K.
 
4/18/2000 2:20 PM
kg

it's not a matter of whether it is crackable or not.  
 
hell, everything is "crackable" when you come right down to it.  
 
it's whether the crack is readily available, like zipped up in a convenient package along with the actual program.  
 
never tried orcad, so i can't comment on its use.  
 
kg
 
4/18/2000 3:47 PM
Liam

Ken,  
 
quote:
"hell, everything is "crackable" when you come right down to it."
 
 
Certainly appears to be the case!  
 
I've actually got a full official version of Orcad, and it's certainly not as user friendly as circuitmaker. Maybe I'm just a bit dim.  
 
On that subject, I posted yesterday about getting those tube models to work in circuitmaker. I'm still having a bit of trouble with that. You couldn't step me through it could you? I can't get any pentode models up and running and I'm not sure how to make the device library aware they exist.  
 
Thanks  
 
Liam
 
4/19/2000 5:48 PM
Stephen Conner

I swear by Orcad PSpice myself (or MicroSim Design Centre as it's now known) I use the student version which is limited to 50 parts.  
 
Steve C.
 

<<First Page<PrevPage 2 of 3 Next> Last Page>>