ampage Tube Amps / Music Electronics	For current discussions, please visit Music Electronics Forum.

ampage archive

Vintage threads from the first ten years

Spice simulations (long)

5/6/1999 8:38 AM
GFR	Spice simulations (long) I've tried Cirmaker and Microcap but both don't give very accurate results when you overdrive things (triodes, BJTs, opamps). I thought the problem could be the models, but after trying MicroSim PSpice I finally got it working. I've found a "generic" Germanium transistor model: .MODEL QGEPNP PNP (IS=5.02N NF=1 BF=308 VAF=101 IKF=.6 ISE=7.32N NE=2 + BR=4 NR=1 VAR=40 IKR=.9 RE=51.5M RB=.206 RC=20.6M XTB=1.5 + CJE=242P VJE=1.1 MJE=.5 CJC=78.1P VJC=.3 MJC=.3 TF=1.38N TR=961N) Using it to simulate a Dallas RM in overdrive I got very nice looking results: an assymetrically clipped waveform with VERY rounded corners. The spectrum showed very few high order harmonics, with the even harmonics stronger than the odd (2nd bigger than 3rd, 4th bigger than 5th, everything else too small). I've also made some computer optimizations to fit a model I've found for triodes to a 12AX7 datasheet. This model takes grid current and the "bending" of curves at low plate voltages (good for simulating starved plate designs and overdriven stages). * 12AX7/ECC81 Triode PSpice Model * copyright (c) 1999 Guilherme F. Ribeiro -- all rights reserved * Based on the 12AT7 model by Mithat Konar * Model used: "Improved VT Models for SPICE Simulations," * Norman Koren, Glass Audio 5/96. * Plate parameters determined by computerized optimization, March 24, 1999. * Plate data from Philips Receiver Tubes Manual. * Interelectrode capacitances are based on data given for Philips ECC83; however, * the reliability of the HF characteristics for this model is probably not * very high. It is likely that that additional complexity will be required * to better model the HF behavior--including the inclusion of heater terminals * in order to explicitly incorporate grid, plate, and cathode to heater * capacitances. And don't forget to add parasitic capacitances of ~0.7 pF * for adjacent pins and ~0.5 pF for others (see Koren's article) as well as for * the effects of a shield (if used). * No guarantees of any kind are made regarding the accuracy or suitability * of any part of this model. Use at your own risk. * * Connections: Plate * ~p~ Grid * ~p~ ~p~ Cathode * ~p~ ~p~ ~p~ .SUBCKT 12AX7 1 2 3 + PARAMS: MU=107.6 EX=1.03 KG1=851 KP=682 KVB=8837 + RGI=2000 + CCG=1.6P CGP=1.6P CCP=0.33P ; E1 7 0 VALUE= +{V(1,3)/KPLOG(1+EXP(KP(1/MU+V(2,3)/SQRT(KVB+V(1,3)*V(1,3)))))} RE1 7 0 1G G1 1 3 VALUE={ (PWR(V(7),EX)+PWRS(V(7), EX))/KG1 } RCP 1 3 1G ; TO AVOID FLOATING NODES IN MU-FOLLOWER C1 2 3 {CCG} ; CATHODE GRID C2 2 1 {CGP} ; GRID-PLATE C3 1 3 {CCP} ; CATHODE-PLATE D3 5 3 DX ; FOR GRID CURRENT R1 2 5 {RGI} ; FOR GRID CURRENT .ENDS 12AX7 .MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N) At http://www.winternet.com/~biro/ you can find models like this for the 6SN7, 12AU7 and 12AT7.

5/6/1999 8:38 AM

GFR

Spice simulations (long)

I've tried Cirmaker and Microcap but both don't give very accurate results when you overdrive things (triodes, BJTs, opamps). I thought the problem could be the models, but after trying MicroSim PSpice I finally got it working.

I've found a "generic" Germanium transistor model:

.MODEL QGEPNP PNP (IS=5.02N NF=1 BF=308 VAF=101 IKF=.6 ISE=7.32N NE=2
+ BR=4 NR=1 VAR=40 IKR=.9 RE=51.5M RB=.206 RC=20.6M XTB=1.5
+ CJE=242P VJE=1.1 MJE=.5 CJC=78.1P VJC=.3 MJC=.3 TF=1.38N TR=961N)

Using it to simulate a Dallas RM in overdrive I got very nice looking results: an assymetrically clipped waveform with VERY rounded corners. The spectrum showed very few high order harmonics, with the even harmonics stronger than the odd (2nd bigger than 3rd, 4th bigger than 5th, everything else too small).

I've also made some computer optimizations to fit a model I've found for triodes to a 12AX7 datasheet. This model takes grid current and the "bending" of curves at low plate voltages (good for simulating starved plate designs and overdriven stages).

* 12AX7/ECC81 Triode PSpice Model
 
* copyright (c) 1999 Guilherme F. Ribeiro -- all rights reserved
 
* Based on the 12AT7 model by Mithat Konar
 
* Model used: "Improved VT Models for SPICE Simulations,"
 
*     Norman Koren, Glass Audio 5/96.
 
* Plate parameters determined by computerized optimization, March 24, 1999.
 
* Plate data from Philips Receiver Tubes Manual.
 
* Interelectrode capacitances are based on data given for Philips ECC83; however,
 
* the reliability of the HF characteristics for this model is probably not
 
* very high. It is likely that that additional complexity will be required
 
* to better model the HF behavior--including the inclusion of heater terminals
 
* in order to explicitly incorporate grid, plate, and cathode to heater
 
* capacitances. And don't forget to add parasitic capacitances of ~0.7 pF
 
* for adjacent pins and ~0.5 pF for others (see Koren's article) as well as for
 
* the effects of a shield (if used).
 
* No guarantees of any kind are made regarding the accuracy or suitability
 
* of any part of this model. Use at your own risk.
 
*
 
* Connections: Plate
 
*              ~p~ Grid
 
*              ~p~ ~p~ Cathode
 
*              ~p~ ~p~ ~p~
 
.SUBCKT 12AX7  1 2 3
 
+ PARAMS: MU=107.6 EX=1.03 KG1=851 KP=682 KVB=8837
 
+ RGI=2000
 
+ CCG=1.6P CGP=1.6P CCP=0.33P ;
 

 
E1	7 	0	VALUE=
 
+{V(1,3)/KP*LOG(1+EXP(KP*(1/MU+V(2,3)/SQRT(KVB+V(1,3)*V(1,3)))))}
 
RE1	7	0	1G
 
G1	1	3	VALUE={ (PWR(V(7),EX)+PWRS(V(7), EX))/KG1 }
 
RCP	1	3	1G		; TO AVOID FLOATING NODES IN MU-FOLLOWER
 
C1	2	3	{CCG}	; CATHODE GRID
 
C2	2	1	{CGP}	; GRID-PLATE
 
C3	1	3	{CCP}	; CATHODE-PLATE
 
D3	5	3	DX		; FOR GRID CURRENT
 
R1	2	5	{RGI}	; FOR GRID CURRENT
 
.ENDS 12AX7
 
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)

At http://www.winternet.com/~biro/ you can find models like this for the 6SN7, 12AU7 and 12AT7.

Page 1 of 1